Script to Disable HP Fingerprint Device

Posted on Updated on

This VBScript is for disabling the Fingerprint device in BIOS.  It has only been tested on a few newer HP models.

'==========================================================================
' AUTHOR: Nick Moseley , https://t3chn1ck.wordpress.com
' DATE  : 5/29/2009
' COMMENT: This script is for disabling the Fingerprint Device in BIOS
' It has been tested on HP models - 6515b, 6535b, 2510p - but may
' function for other models
'==========================================================================
Option Explicit
Const ForAppending = 8
Const wbemFlagReturnImmediately = 16
Const wbemFlagForwardOnly = 32
Dim oFSO, oFile, oWMI_BIOSSettingInterface, oItem, colItems, lFlags, iReturnValue 
 
' Open Log File
Set oFSO = CreateObject("Scripting.fileSystemObject")
Set oFile = oFSO.OpenTextFile ("C:\DisableFingerprintDevice.txt", ForAppending, True)
 
' Query WMI
lFlags = wbemFlagReturnImmediately + wbemFlagForwardOnly
Set oWMI_BIOSSettingInterface = GetObject("winmgmts:{impersonationlevel=impersonate}//./root/HP/InstrumentedBIOS")
Set colItems = oWMI_BIOSSettingInterface.ExecQuery("select * from HP_BIOSSettingInterface",,lFlags) 
 
' Configure Fingerprint Device to be disabled
For Each oItem In colItems 
  oItem.SetBIOSSetting iReturnValue, "Fingerprint Device", "Disable"
Next 
 
' If change was successful (exit code 0) then log
If iReturnValue = 0 Then
 WScript.Echo "Completed with: " & iReturnValue
 oFile.WriteLine "Disabled Fingerprint Device in BIOS (" & Date & " " & Time & ")"
Else
 oFile.WriteLine("FAILURE: Could not disable Fingerprint Device, option not found in BIOS (" & Date & " " & Time & ")")
End If 
 
oFile.Close
WScript.Quit ()

Advertisements

Leave a Reply

Fill in your details below or click an icon to log in:

WordPress.com Logo

You are commenting using your WordPress.com account. Log Out / Change )

Twitter picture

You are commenting using your Twitter account. Log Out / Change )

Facebook photo

You are commenting using your Facebook account. Log Out / Change )

Google+ photo

You are commenting using your Google+ account. Log Out / Change )

Connecting to %s